[src/trunk]: src/sys/arch/usermode/conf Where did kern.ldscript go?

[reinoud <reinoud%NetBSD.org@localhost>]

details:   https://anonhg.NetBSD.org/src/rev/e9490ef9e674
branches:  trunk
changeset: 361909:e9490ef9e674
user:      reinoud <reinoud%NetBSD.org@localhost>
date:      Fri May 18 19:04:10 2018 +0000

description:
Where did kern.ldscript go?

diffstat:

 sys/arch/usermode/conf/kern.ldscript |  73 ++++++++++++++++++++++++++++++++++++
 1 files changed, 73 insertions(+), 0 deletions(-)

diffs (77 lines):

diff -r d638a574c3ee -r e9490ef9e674 sys/arch/usermode/conf/kern.ldscript
--- /dev/null   Thu Jan 01 00:00:00 1970 +0000
+++ b/sys/arch/usermode/conf/kern.ldscript      Fri May 18 19:04:10 2018 +0000
@@ -0,0 +1,73 @@
+/*     $NetBSD: kern.ldscript,v 1.1 2018/05/18 19:04:10 reinoud Exp $  */
+
+#include "assym.h"
+
+ENTRY(_start)
+SECTIONS
+{
+       /* Read-only sections, merged into text segment: */
+       .text :
+       {
+               *(.text)
+               *(.text.*)
+               *(.stub)
+       }
+       _etext = . ;
+       PROVIDE (etext = .) ;
+
+       .rodata :
+       {
+               *(.rodata)
+               *(.rodata.*)
+       }
+
+       /*
+        * Adjust the address for the data segment.  We want to adjust up to
+        * the same address within the page on the next page up.
+        */
+       . = ALIGN(0x100000) + (. & (0x100000 - 1));
+       __data_start = . ;
+       .data :
+       {
+               *(.data)
+       }
+
+       . = ALIGN(COHERENCY_UNIT);
+       .data.cacheline_aligned :
+       {
+               *(.data.cacheline_aligned)
+       }
+       . = ALIGN(COHERENCY_UNIT);
+       .data.read_mostly :
+       {
+               *(.data.read_mostly)
+       }
+       . = ALIGN(COHERENCY_UNIT);
+
+       _edata = . ;
+       PROVIDE (edata = .) ;
+       __bss_start = . ;
+       .bss :
+       {
+               *(.bss)
+               *(.bss.*)
+               *(COMMON)
+               . = ALIGN(64 / 8);
+       }
+       . = ALIGN(64 / 8);
+       _end = . ;
+       PROVIDE (end = .) ;
+       .note.netbsd.ident :
+       {
+               KEEP(*(.note.netbsd.ident));
+       }
+}
+
+SECTIONS
+{
+       .text :
+       AT (ADDR(.text) & 0x0fffffff)
+       {
+               *(.text)
+       } = 0
+}